it-swarm.dev

Jak znaleźć rzeczywiste miejsce zajmowane przez indeksy na stole w Oracle?

Chcę znaleźć rzeczywiste miejsce zajmowane przez indeksy na stole w Oracle 10g. Nie zamierzam uwzględniać miejsca zarezerwowanego przez Oracle do wykorzystania w przyszłości. (Nie należy brać pod uwagę narzutu Oracle). Chcę, aby używane bajty nie były przydzielonymi bajtami.

Pomożesz mi iść naprzód?

Jest też sposób na znalezienie rzeczywistej wielkości długiego pola w tabeli.

PS: vsize () i dbms_lob.getlength () nie działają.

11
Egalitarian
SELECT idx.index_name, SUM(bytes)
  FROM dba_segments seg,
       dba_indexes  idx
 WHERE idx.table_owner = <<owner of table>>
   AND idx.table_name  = <<name of table>>
   AND idx.owner       = seg.owner
   AND idx.index_name  = seg.segment_name
 GROUP BY idx.index_name

pokaże Ci ilość miejsca faktycznie zużytego przez każdy indeks. Nie jestem pewien, czy dokładnie tego rodzaju koszty ogólne próbujesz uwzględnić i jak rozróżniasz „używane” i „alokowane” w kontekście indeksu. Jeśli chcesz uwzględnić wolne miejsce w indeksie, możesz użyć procedura DBMS_SPACE.SPACE_USAGE , aby określić liczbę częściowo pustych bloków w indeksie.

8
Justin Cave

Aby zmierzyć (przypuszczam, że rozumiesz) przydzielony i używany rozmiar indeksu, prawdopodobnie użyłbym dbms_space

create or replace procedure tq84_index_size_proc 
as

  OBJECT_OWNER_in         varchar2(30) :=  user;
  OBJECT_NAME_in          varchar2(30) := 'TQ84_SIZE_IX';
  OBJECT_TYPE_in          varchar2(30) := 'INDEX';
  SAMPLE_CONTROL_in       number       :=  null;
  SPACE_USED_out          number;
  SPACE_ALLOCATED_out     number;
  CHAIN_PCENT_out         number;

  SUM_SEGMENT             number;

begin

  dbms_space.object_space_usage (
    OBJECT_OWNER           => OBJECT_OWNER_in        ,
    OBJECT_NAME            => OBJECT_NAME_in         ,
    OBJECT_TYPE            => OBJECT_TYPE_in         ,
    SAMPLE_CONTROL         => SAMPLE_CONTROL_in      ,
    SPACE_USED             => SPACE_USED_out         ,
    SPACE_ALLOCATED        => SPACE_ALLOCATED_out    ,
    CHAIN_PCENT            => CHAIN_PCENT_out
  );

  select sum(bytes) into SUM_SEGMENT 
    from user_segments
   where segment_name = OBJECT_NAME_in;


  dbms_output.put_line('Space Used:      ' || SPACE_USED_out);
  dbms_output.put_line('Space Allocated: ' || SPACE_ALLOCATED_out);
  dbms_output.put_line('Segment:         ' || SUM_SEGMENT);

end;
/

Ta procedura mierzy przydzielony i używany rozmiar indeksu o nazwie * TQ84_SIZE_IX *. Dla kompletności dodałem również liczbę bajtów zgłoszoną przez user_segments.

Teraz tę procedurę można zobaczyć w akcji:

create table tq84_size (
  col_1 varchar2(40),
  col_2 number
);

create index tq84_size_ix on tq84_size(col_1);

insert into tq84_size values ('*', 0);
commit;
exec tq84_index_size_proc;

Po wprowadzeniu jednego indeksu zwracane są następujące liczby:

Space Used:      1078
Space Allocated: 65536
Segment:         65536

Wypełnianie indeksu ...

insert into tq84_size 
select substr(object_name || object_type, 1, 40),
       rownum
  from dba_objects,
       dba_types
 where rownum < 500000;
commit;

... i znów zdobywam liczby ...

exec tq84_index_size_proc;

... raporty:

Space Used:      25579796
Space Allocated: 32505856
Segment:         32505856

Następnie, jeśli indeks zostanie „opróżniony”:

delete from tq84_size;
commit;
exec tq84_index_size_proc;

to pokazuje:

Space Used:      4052714
Space Allocated: 32505856
Segment:         32505856

co pokazuje, że przydzielony rozmiar nie zmniejsza się, gdy używany jest rozmiar.

6

W przypadku, gdy ktoś tu przyjdzie i szuka sposobu na znalezienie wielkości długiego pola, poniżej można to zrobić. Usunę tę odpowiedź, jeśli pytanie zostanie rozdzielone.

Przykładowe dane...

CREATE TABLE TLONG 
(
  C1 Number(3),
  C2 LONG 
);

INSERT INTO TLONG VALUES (1,'abcd');
INSERT INTO TLONG VALUES (2,'abc');
INSERT INTO TLONG VALUES (3,'ab');
INSERT INTO TLONG VALUES (4,'1234567890');

Funkcja do wykonania pracy ... (Do produkcji powinna być w pakiecie)

CREATE OR REPLACE FUNCTION GetLongLength (pKey Number) RETURN Number Is
   vLong Long;
BEGIN
   SELECT C2 INTO vLong FROM TLONG WHERE C1 = pKey;
   Return Length(vLong);
END;
/

SHOW ERRORS;

Przetestuj funkcję ...

SELECT rownum, GetLongLength(rownum) FROM dual CONNECT BY rownum<=4;

ROWNUM                 GETLONGLENGTH(ROWNUM)  
---------------------- ---------------------- 
1                      4                      
2                      3                      
3                      2                      
4                      10                   
2
Leigh Riffel

Musiałem zmodyfikować odpowiedź René Nyffeneggera, aby uczynić ją bardziej ogólną i łatwiej zobaczyć wykorzystanie miejsca dla wszystkich indeksów w schemacie.

Pomyślałem, że podzielę się tutaj zmodyfikowanym kodem, na wypadek gdyby ktokolwiek uznał go za przydatny:

--==========================================
-- Show space usage by all indexes in schema
--==========================================
-- Required to show output in SQLDeveloper, which would supress it otherwise.
SET SERVEROUTPUT ON;
-- Calculates size for given index
CREATE OR REPLACE PROCEDURE calc_index_size(
    index_name IN VARCHAR2)
AS
  OBJECT_OWNER_in     VARCHAR2(30) := USER;
  OBJECT_NAME_in      VARCHAR2(30) := index_name;
  OBJECT_TYPE_in      VARCHAR2(30) := 'INDEX';
  SAMPLE_CONTROL_in   NUMBER       := NULL;
  SPACE_USED_out      NUMBER;
  SPACE_ALLOCATED_out NUMBER;
  CHAIN_PCENT_out     NUMBER;
  SUM_SEGMENT         NUMBER;
BEGIN
  dbms_space.object_space_usage ( OBJECT_OWNER => OBJECT_OWNER_in , OBJECT_NAME => OBJECT_NAME_in , OBJECT_TYPE => OBJECT_TYPE_in , SAMPLE_CONTROL => SAMPLE_CONTROL_in , SPACE_USED => SPACE_USED_out , SPACE_ALLOCATED => SPACE_ALLOCATED_out , CHAIN_PCENT => CHAIN_PCENT_out );
  SELECT SUM(bytes)
  INTO SUM_SEGMENT
  FROM user_segments
  WHERE segment_name = OBJECT_NAME_in;
  dbms_output.put_line('Space Used:      ' || ROUND(SPACE_USED_out     /1024/1024, 2) || 'MB');
  dbms_output.put_line('Space Allocated: ' || ROUND(SPACE_ALLOCATED_out/1024/1024) || 'MB');
  dbms_output.put_line('Segment:         ' || ROUND(SUM_SEGMENT        /1024/1024) || 'MB');
END;
/
-- Shows index size for all indexes in a schema
DECLARE
BEGIN
  FOR user_indexes_sorted_by_size IN
  (SELECT idx.index_name,
    SUM(bytes)/1024/1024 AS "Size(MB)"
  FROM user_segments seg,
    user_indexes idx
  WHERE idx.index_name = seg.segment_name
  GROUP BY idx.index_name
  ORDER BY "Size(MB)" DESC
  )
  LOOP
    dbms_output.put_line( user_indexes_sorted_by_size.index_name );
    dbms_output.put_line( '-------------------------------------' );
    calc_index_size(user_indexes_sorted_by_size.index_name);
    dbms_output.put_line( '' );
  END LOOP;
END;
--==========================================
--==========================================
0
Kshitiz Sharma